REM -------- SizMan ----------------------------------------------
REM        Mandelbrot Set of the sin map
REM
REM              f(z)=C*sin(z),    C=a+i*b
REM
REM   Cを与えて 点 A=(π/2,0) の軌道 O+(A) が発散するか否かを調べる
REM          発散の時  黄または赤（黒以外）
REM          発散しない時  黒
REM    発散は，|Yn|>60  or |Xn|>60 で判定
rem 
REM -------------------------------------- Joe --- 2.18 '19 ---------
dim it(0 to 5000),b(20),co(20)
line input prompt"テスト用(T)ですか本番用(H)ですか？  T/H=":tq$
if tq$="H" or tq$="h" then goto 10
LET  txl=.3
LET  txu=.5
LET  tyl=.6
LET  tyu=.8
LET  n1=200
goto 20
10 LET  txl=.1
   LET  txu=.9
   LET  tyl=.1
   LET  tyu=.9
   LET  n1=600
20 LET  r=1.e+06
   input prompt"iteration の回数(100以上)=":tm
   rem   print"カラーのinput、外側の色から8個入れよ"
   rem   input co(1),co(2),co(3),co(4),co(5),co(6),co(7),co(8)
   for k=1 to 8
      read co(k)
   NEXT k
   REM   DATA 10,2,8,15,4,7,6,5
   REM DATA 2,6,3,3,4,4,4,4
   DATA 13,6,4,4,3,3,3,3
   rem ---------------------
   LET  b(9)=tm
   for i= 8 to 1 step -1
      LET  b(i)=int(b(i+1)/1.66+.5)
   next i
   LET  b(1)=1
   PRINT "計算する４角形(C-plane)のinput"
   INPUT PROMPT"c-planeの実軸=":xl,xu
   INPUT PROMPT"c-planeの虚軸=":yl,yu
   rem
   rem    画像パラメ−タ−設定
   rem
   LET  wx=xu-xl
   LET  wy=yu-yl
   LET  twx=txu-txl
   LET  twy=tyu-tyl
   LET  dx=wx/n1
   LET  dy=wy/n1
   LET  a1=twx/wx
   LET  a2=twy/wy
   LET  b1=(xu*txl-xl*txu)/wx
   LET  b2=(yu*tyl-yl*tyu)/wy
   set area color 1
   plot area: txl,tyl;txu,tyl;txu,tyu;txl,tyu;txl,tyl
   PLOT TEXT, AT 0.04,.95:"Mandel-Set, C-plane 範囲："
   PLOT TEXT, AT .4,.95,USING"###.##### ###.#####":xl,xu
   PLOT TEXT, AT .7,.95,USING"###.##### ###.#####":yl,yu
   for i=0 to tm+1
      LET  it(i)=0
   next i
   set point style 1
   rem
   REM     反復開始        
   rem
   for i=0 to n1
      for j=0 to n1
         LET  ar=xl+i*dx
         LET  ai=yl+j*dy
         LET  t=0
         LET  x=ar
         LET  y=ai
         rem --------------------------
50       LET  x1=ar*(EXP(y)+EXP(-y))/2*SIN(x)-ai*(EXP(y)-EXP(-y))/2*COS(x)
         LET  y1=ar*(EXP(y)-EXP(-y))/2*COS(x)+ai*(EXP(y)+EXP(-y))/2*SIN(x)
         LET  d2=x1*x1+y1*y1
         LET  t=t+1
         IF ABS(y1)>60 OR ABS(x1)>60 THEN GOTO 60
         if t<tm then goto 55 else goto 57
55       LET  x=x1
         LET  y=y1
         goto 50 
57       LET  it(t)=it(t)+1
         goto 90
         rem -------------塗り絵
60       LET  it(t)=it(t)+1
         for k=1 to 8
            if b(k)<=t and t<b(k+1) then goto 70
         next k
70       set point color co(k)
         LET  tx=a1*ar+b1
         LET  ty=a2*ai+b2
         plot points:tx,ty
90    next j
   next i
   rem
   rem    計算終り
   rem
   for i=1 to 9
      print b(i);
   next i
   print" "
   LET  k1=int(tm/10)
   for i=1 to k1
      for j=1 to 10
         LET  k=(i-1)*10+(j-1)
         print it(k);
      next j
      print" "
   next i
   if k<tm then goto 95 else goto 99
95 for i=k+1 to tm
      print it(i);
   next i
99 line input prompt"ファイル名つけるか？y/n":fa$
   if fa$="N" or fa$="n" then goto 100
   PRINT"ファイル名inpuせよ（例） sim-01, sim-06, , など"
   line input prompt"ファイル名=":na$
   PLOT TEXT, AT .05,.05:"ファイル名："
   PLOT TEXT, AT .2, .05:na$
   PRINT"コメントinpuせよ（全角20文字以下)"
   LINE INPUT PROMPT"コメント=":na$
   PLOT TEXT, AT .05,.01:"コメント："
   PLOT TEXT, AT .2, .01:na$
100 PLOT TEXT, AT .68,.05:"反復回数="
    PLOT TEXT, AT .79,.05,USING"#####.":tm
    print"＝＝＝最後に絵のセーブ忘れずに＝＝＝"
 END